Area list ¦ Missing house numbers ¦ Call Overpass to update ¦ View query ¦ Existing house numbers ¦ Existing streets ¦
Overpass turbo ¦ Area boundary

[out:csv(::id, name, highway, service, surface, leisure, ::type)]  [timeout:425];
area(3601746619)->.searchArea;
// all but service, footway, path + avoid bridges and special highways
way(area.searchArea)[highway][name][!"bridge"]["highway"!~"platform|bus_stop|footway|steps|raceway|service|pedestrian|proposed|abandoned|rest_area|path"];
out;
// service roads with names, avoid parking ways, drive-through
way(area.searchArea)[highway=service][name][!"bridge"][service!~"parking_aisle|drive-through|slipway"];
out;
// avoid underpass and bridge footways
way(area.searchArea)["highway"~"footway|steps|pedestrian"][name][layer!~"-"][!"bridge"];
out;
// path with valid street name, try to exclude hiking path with comments in name tag
way(area.searchArea)["highway"="path"][name][name~"utca|út|köz|árok|lépcső|gát|part|tér|tere|sétány|park|dűlő|sor|kert"][name!~"garázssor"](area.searchArea);
out;
// include parking aisle with valid street name
way(area.searchArea)["highway"="service"][service="parking_aisle"][name][name~"utca|köz|sétány|tér|tere"](area.searchArea);
out;
// include amenity parking  with valid street name
way(area.searchArea)["amenity"="parking"][!highway][name~" utca$| köz$| sétány$| tér$| tere$| udvar$"][!"addr:street"][name!~"gazdasági udvar"](area.searchArea);
out;
// include parks with names
way(area.searchArea)["leisure"="park"][name];
out;
relation(area.searchArea)["leisure"="park"][name];
out;
// area boundary streets
rel(1746619)->.searchRelation;
way(r.searchRelation)[highway][name][!"bridge"];
out;
// highway=track can also be anonymous, but many mistag based on road surface

Version: v7.2-208-gccbc6f9 ¦ OSM data © OpenStreetMap contributors. ¦ Last update: 2021-10-18 00:23